रीफ्रेश या ताज़ा करने के बाद मैक्रो को कैसे कॉल करें सभी बटन दबाए गए?

Question

आखिरकार, मैं किसी भी कार्यपुस्तिका को रीफ्रेश करने के बाद मैक्रो चलाने के लिए विशेष रूप से ताज़ा करना चाहता हूं, विशेष रूप से एक्सेल में डेटा टैब के नीचे ताज़ा बटन का उपयोग करना। हालांकि, समय के लिए, मैं केवल रीफ्रेश बटन दबाकर आग लगने के लिए पहले रीफ्रेश या आफ्टर रीफ्रेश क्वेरीटेबल ईवेंट प्राप्त करने से संतुष्ट होगा।

'प्रलेखन' माइक्रोसॉफ्ट देव केंद्र वेबसाइट पर की पेशकश की के अलावा, प्रासंगिक पोस्ट मैं इस अनुसंधान की प्रक्रिया के हिस्से के रूप में पढ़ा है में शामिल हैं:

• Excel VBA - QueryTable AfterRefresh function not being called after Refresh completes
• VBA For Excel AfterRefresh Event
• वहाँ अन्य रहे हैं कम सहायक या प्रासंगिक पोस्ट लेकिन मुझे यहां पोस्ट करने की प्रतिष्ठा नहीं है।

मैं स्पष्ट रूप से कुछ महत्वपूर्ण (और सबसे अधिक संभावना स्पष्ट) याद कर रहा हूं। यहाँ है कि मैं क्या अभी तक है:

के तहत कक्षा मॉड्यूल (qtclass)

Option Explicit 

Private WithEvents qt As Excel.QueryTable 

Private Sub qt_AfterRefresh(ByVal Success As Boolean) 

    MsgBox "qt_AfterRefresh called sucessfully." 
    If Success = True Then 
     Call Module2.SlicePivTbl 
     MsgBox "If called succesfully." 
    End If 

End Sub 

Private Sub qt_BeforeRefresh(Cancel As Boolean) 
    MsgBox "qt_BeforeRefresh called." 
End Sub 

ThisWorkbook मॉड्यूल

Private Sub Workbook_Open() 

    Dim qtevent As qtclass 
    Dim qt As QueryTable 
    Set qt = ThisWorkbook.Worksheets("Data-Fund").ListObjects(1).QueryTable 
    Set qtevent = New qtclass 

End Sub 

मैं विशिष्ट कार्यपत्रकों के तहत दूसरा कोड ब्लॉक के रूपों के रूप में अच्छी तरह से कोशिश की है के तहत , लेकिन अभी तक काम करने वाली कुछ भी नहीं है। वर्कशीट मॉड्यूल में प्रश्न में क्वेरीरटेबल को किसी भी तरह से मंद करने की ज़रूरत है? जो भी मैं याद कर रहा हूं उस पर कोई सुझाव या विचारों की सराहना की जाएगी।

Answer 1

आपने वास्तव में कक्षा उदाहरण में क्वेरीटेबल को कनेक्ट नहीं किया है। qtclass

Option Explicit 

Private WithEvents qt As Excel.QueryTable 
Public Property Set HookedTable(q As Excel.QueryTable) 
    Set qt = q 
End Property 

Private Sub qt_AfterRefresh(ByVal Success As Boolean) 

    MsgBox "qt_AfterRefresh called sucessfully." 
    If Success = True Then 
     Call Module2.SlicePivTbl 
     MsgBox "If called succesfully." 
    End If 

End Sub 

Private Sub qt_BeforeRefresh(Cancel As Boolean) 
    MsgBox "qt_BeforeRefresh called." 
End Sub 

न्यू ThisWorkbook कोड संशोधित:

Dim qtevent As qtclass 
Private Sub Workbook_Open() 

    Set qtevent = New qtclass 
    Set qtevent.HookedTable = ThisWorkbook.Worksheets("Data-Fund").ListObjects(1).QueryTable 

End Sub 

ध्यान दें कि यह काफी बारीकी से युग्मित है। यदि आप कक्षा में घटनाओं को उठाना चाहते हैं और अपने qtevent variable WithEvents घोषित करना चाहते हैं तो यह अधिक उपयोग करने योग्य होगा।