TListView और माउस व्हील स्क्रॉलिंग

Question

मेरे पास एक रूप में एक TListView घटक है। यह काफी लंबा है और मैं चाहता हूं कि उपयोगकर्ता इसे स्क्रॉल करने में सक्षम हो, अगर माउस घटक पर है और पहिया स्क्रॉल किया गया है। मुझे TListView ऑब्जेक्ट के लिए कोई ऑनमहाउसहेल, ऑनमोउसहेलडाउन या ऑनमोउसहेलअप ईवेंट नहीं मिला है। मैं उसे कैसे कर सकता हूँ?

सादर, evilone

Answer 1

यहाँ यह करने के लिए मेरे कोड है:

type 
    TMyListView = class(TListView) 
    protected 
    function DoMouseWheelDown(Shift: TShiftState; MousePos: TPoint): Boolean; override; 
    function DoMouseWheelUp(Shift: TShiftState; MousePos: TPoint): Boolean; override; 
    end; 

type  
    TMouseWheelDirection = (mwdUp, mwdDown); 

function GenericMouseWheel(Handle: HWND; Shift: TShiftState; WheelDirection: TMouseWheelDirection): Boolean; 
var 
    i, ScrollCount, Direction: Integer; 
    Paging: Boolean; 
begin 
    Result := ModifierKeyState(Shift)=[];//only respond to un-modified wheel actions 
    if Result then begin 
    Paging := DWORD(Mouse.WheelScrollLines)=WHEEL_PAGESCROLL; 
    ScrollCount := Mouse.WheelScrollLines; 
    case WheelDirection of 
    mwdUp: 
     if Paging then begin 
     Direction := SB_PAGEUP; 
     ScrollCount := 1; 
     end else begin 
     Direction := SB_LINEUP; 
     end; 
    mwdDown: 
     if Paging then begin 
     Direction := SB_PAGEDOWN; 
     ScrollCount := 1; 
     end else begin 
     Direction := SB_LINEDOWN; 
     end; 
    end; 
    for i := 1 to ScrollCount do begin 
     SendMessage(Handle, WM_VSCROLL, Direction, 0); 
    end; 
    end; 
end; 

function TMyListView.DoMouseWheelDown(Shift: TShiftState; MousePos: TPoint): Boolean; 
begin 
    //don't call inherited 
    Result := GenericMouseWheel(Handle, Shift, mwdDown); 
end; 

function TMyListView.DoMouseWheelUp(Shift: TShiftState; MousePos: TPoint): Boolean; 
begin 
    //don't call inherited 
    Result := GenericMouseWheel(Handle, Shift, mwdUp); 
end; 

GenericMouseWheel काफी गंधा है। यह एक लंबवत स्क्रॉल बार के साथ किसी भी नियंत्रण के लिए काम करता है। मैं इसे पेड़ के दृश्यों, सूची दृश्यों, सूची बक्से, मेमो, समृद्ध संपादन आदि के साथ उपयोग करता हूं।

आप मेरी ModifierKeyState दिनचर्या खो देंगे लेकिन आप यह जांचने के लिए अपनी स्वयं की विधि को प्रतिस्थापित कर सकते हैं कि व्हील इवेंट संशोधित नहीं है। कारण आप ऐसा करना चाहते हैं, उदाहरण के लिए, CTRL + माउस व्हील स्क्रॉल के बजाय ज़ूम का अर्थ है।

क्या इसके लायक है के लिए, यह इस तरह दिखता है:

type 
    TModifierKey = ssShift..ssCtrl; 
    TModifierKeyState = set of TModifierKey; 

function ModifierKeyState(Shift: TShiftState): TModifierKeyState; 
const 
    AllModifierKeys = [low(TModifierKey)..high(TModifierKey)]; 
begin 
    Result := AllModifierKeys*Shift; 
end;