एक संग्रहीत प्रक्रिया

Question

के माध्यम से एसक्यूएल से बाइनरी फ़ाइल डेटा (छवियों) का निर्यात करना मैं एक बड़ी संख्या में छवि फ़ाइलों को निर्यात करने की कोशिश कर रहा हूं, जो आंतरिक रूप से SQL डेटाबेस में बाइनरी डेटा के रूप में संग्रहीत हैं।

एसक्यूएल में संग्रहीत प्रक्रियाओं को लिखने के लिए काफी नया होने के नाते, मैं कुछ उपयोगी मार्गदर्शिकाओं में आया हूं कि इसे कैसे संग्रहीत किया जा सकता है, लेकिन मुझे कुछ याद आ रहा है।

मैं स्थानीय रूप से SQL Server 2008 R2 चला रहा हूं, और मैं फ़ाइलों को अपने सी: \ ड्राइव पर किसी फ़ोल्डर में लिखने की कोशिश कर रहा हूं।

यहाँ मैं अब तक राशि का व्यापार हिस्सा है:

BEGIN 
DECLARE @cmd VARCHAR(8000) 
DECLARE @result int 

DECLARE curExportBinaryDocs CURSOR FAST_FORWARD FOR 
SELECT 'BCP "SELECT Photograph_Data FROM [ALBSCH Trial].[dbo].[Photograph] WHERE Photograph_ID = ' 
    + CAST(Photograph_ID AS VARCHAR(500)) + '" queryout "' + @OutputFilePath 
    + CAST(Photograph_ID AS VARCHAR(500)) + '.jpg"' + ' -n -T' 
FROM dbo.Photograph 

OPEN curExportBinaryDocs 
FETCH NEXT FROM curExportBinaryDocs INTO @cmd 
WHILE @@FETCH_STATUS = 0 
    BEGIN 
    --PRINT @cmd 
    EXEC @result = xp_cmdshell @cmd   
    FETCH NEXT FROM curExportBinaryDocs INTO @cmd 
    END 
CLOSE curExportBinaryDocs 
DEALLOCATE curExportBinaryDocs 
END 

'@result' हमेशा '1' के लिए सेट किया जा रहा है (विफल) xp_cmdshell कॉल के बाद। सभी टेबल नाम/फ़ील्ड सही हैं, इसलिए मुझे संदेह है कि मेरे बीसीपी कॉल में कुछ गड़बड़ है, लेकिन मुझे यकीन नहीं है कि आगे क्या प्रयास करना है।

कोई भी मदद या सलाह का स्वागत किया जाएगा।

Answer 1

ठीक है, सब .. की पहली (और अत: क्षमा करें;)) डॉन "टी उपयोग कर्सर .. और खेद टोपियां के लिए ...

कर्सर के बारे में सबसे baddest बातों में से एक यह है कि कर रहे हैं वे अपनी मेज लॉक कर सकते हैं। क्या मैं हमेशा इन उद्देश्यों के लिए करते हैं (और जो काफी तेजी से किया जाता है), मैं पाश के लिए एक का उपयोग .. इस

declare @totrow int 
     , @currow int 
     , @result int 
     , @nsql nvarchar(max) 

declare @sqlStatements table (
    Id int identity(1, 1) 
, SqlStatement varchar(max) 
) 
insert 
into @sqlStatements 
select 'QUERY PART' 
from table 

set @totrow = @@rowcount 
set @currow = 1 
while @totrow > 0 and @currow <= @totrow 
begin 
    select @nsql = SqlStatement 
    from @SqlStatements 
    where Id = @currow 

    exec @result = xp_cmdshell @nsql 

    set @currow = @currow + 1 
end 

अगले भाग के लिए की तरह, एसक्यूएल सर्वर प्रक्रिया के लिए पर्याप्त अनुमति नहीं है करता है सी: ड्राइव को लिखें? इसके अलावा, जब आप अपना कोड निष्पादित करते हैं तो अपने संदेश फलक में देखें, शायद आप वहां कुछ पा सकते हैं?

आप क्या कर सकते हैं, इसे मैन्युअल रूप से निष्पादित करने का प्रयास करें। बस एक बीसीपी कथन प्राप्त करें और इसे xp_cmdshell के साथ निष्पादित करें। क्या यह कोई त्रुटि देता है?

Answer 2

यहां मेरी अंतिम कार्यप्रणाली और प्रारूप फ़ाइल है। मैं बीसीपी कमांड, अनुमति सेटिंग्स और फ़ाइल फ़ाइल लेआउट को एक ही स्थान पर बेहतर विवरण नहीं ढूंढ पाया, इसलिए शायद यह किसी के लिए उपयोग किया जाएगा।

CREATE PROCEDURE [dbo].[ImgExport] 
    @OutputFilePath VARCHAR(500) = 'C:\SQLTest\ ' 
AS 
BEGIN 
    DECLARE @totrow int 
    DECLARE @currow int 
    DECLARE @result int 
    DECLARE @nsql nvarchar(4000) 
    DECLARE @sqlStatements table (ID int IDENTITY(1, 1), SqlStatement varchar(max)) 

    INSERT 
    INTO @sqlStatements 
    SELECT 'BCP "SELECT Photograph_Data FROM [ALBSCH_Trial].[dbo].[Photograph] WHERE Photograph_ID = ''' 
    + CAST(Photograph_ID AS VARCHAR(500)) + '''" queryout ' + @OutputFilePath 
    + CAST(Photograph_ID AS VARCHAR(500)) + '.jpg -S localhost\SQLEXPRESS2008 -T -f C:\SQLTest\Images.fmt' 
    FROM dbo.Photograph 

    SET @totrow = @@ROWCOUNT 
    SET @currow = 1 
    WHILE @totrow > 0 and @currow <= @totrow 
    BEGIN 
     SELECT @nsql = SqlStatement 
     FROM @sqlStatements 
     WHERE ID = @currow 
     EXEC @result = xp_cmdshell @nsql 
     SET @currow = @currow + 1 
    END 
END  

स्वरूप फ़ाइल:

9.0 
1 
1  SQLBINARY  0  0  "\t"  1  Photograph_Data         "" 

मुझे आशा है कि किसी को मदद मिलती है।