2 delimiters

Question

का उपयोग कर एक टेक्स्ट फ़ाइल से स्ट्रिंग निकालें मैं 2 delimiters का उपयोग कर एक पाठ फ़ाइल से एक स्ट्रिंग निकालने की कोशिश कर रहा हूँ। एक शुरू करने के लिए और एक रोकने के लिए।

उदाहरण:

Hi my name is$John and I'm happy/today 

मैं क्या करने की जरूरत एक समारोह है कि $ और / के बीच स्ट्रिंग वापसी होगी कॉल करने के लिए है। मैं हर जगह देख रहा हूं लेकिन मुझे कुछ उपयोगी नहीं लगता है और मैं प्रोग्रामिंग के लिए नया हूं।

Answer 1

आप Pos और Copy साथ यह कर सकते हैं:

function ExtractText(const Str: string; const Delim1, Delim2: char): string; 
var 
    pos1, pos2: integer; 
begin 
    result := ''; 
    pos1 := Pos(Delim1, Str); 
    pos2 := Pos(Delim2, Str); 
    if (pos1 > 0) and (pos2 > pos1) then 
    result := Copy(Str, pos1 + 1, pos2 - pos1 - 1); 
end; 

Answer 2

मैं इसे इस तरह कुछ करना चाहते हैं:

function ExtractDelimitedString(const s: string): string; 
var 
    p1, p2: Integer; 
begin 
    p1 := Pos('$', s); 
    p2 := Pos('/', s); 
    if (p1<>0) and (p2<>0) and (p2>p1) then begin 
    Result := Copy(s, p1+1, p2-p1-1); 
    end else begin 
    Result := '';//delimiters not found, or in the wrong order; raise error perhaps 
    end; 
end; 

Answer 3

बकवाद, आप एक TFileStream वर्ग का उपयोग कर यह करने के लिए एक समारोह में लिख सकते हैं , और Copy और Pos फ़ंक्शंस।

इस नमूने देखें:

uses 
    Classes, 
    SysUtils; 

function ExtractString(Const FileName: TFileName;Const IDel,FDel : AnsiString) : AnsiString; 
Var 
FileStream : TFileStream; 
i,f  : Integer; 
begin 
    FileStream:= TFileStream.Create(FileName, fmOpenRead or fmShareDenyWrite); //oopen the file 
    try 
    try 
     SetLength(Result, FileStream.Size); //set the size of the string 
     FileStream.Read(Pointer(Result)^, FileStream.Size);//read the content into a string 
     i:=Pos(IDel,Result);//search the initial delimiter 
     f:=Pos(FDel,Result);//search the final delimiter 
     Result:=Copy(Result,i+1,f-i-1); //extract the value between the delimiters 
    except 
     Result := ''; 
     raise; 
    end; 
    finally 
    FileStream.Free; 
    end; 
end; 

और इस तरह से

ExtractString('your_file_name','$','/'); 

Answer 4

दोनों सीमांकक मान लिया जाये कि में उपयोग अपनी पोस्ट के अनुसार एकल वर्ण हैं:

function ExtractDelimitedValueFromFile(const aFilename: String; 
             const aOpenDelim: Char; 
             const aCloseDelim: Char; 
             var aValue: String): Boolean; 
var 
    i: Integer; 
    strm: TStringStream; 
    delimStart: Integer; 
    delimEnd: Integer; 
begin 
    result  := FALSE; 
    aValue  := ''; 
    delimStart := -1; 
    delimEnd := -1; 

    strm := TStringStream.Create; 
    try 
    strm.LoadFromFile(aFileName); 

    for i := 1 to strm.Size do 
    begin 
     if (delimStart = -1) and (strm.DataString[i] = aOpenDelim) then 
     delimStart := i 
     else if (delimStart <> -1) and (strm.DataString[i] = aCloseDelim) then 
     delimEnd := i; 

     result := (delimStart <> -1) and (delimEnd <> -1); 
     if result then 
     begin 
     aValue := Copy(strm.DataString, delimStart + 1, delimEnd - delimStart - 1); 
     BREAK; 
     end; 
    end; 

    finally 
    strm.Free; 
    end; 
end; 

उपयोग:

var 
    str: String; 
    begin 
    if ExtractDelimitedValueFromFile('path\filename.ext', '$', '/', str) then 
     // work with str 
    else 
     // delimited value not found in file 
    end; 

Answer 5

नए डेल्फी के आप इसे इस तरह से कर सकते हैं में .. (Yay)

program Project40; {$APPTYPE CONSOLE} 

uses RegularExpressions; 

const 
    str = 'Is$John and I''m happy/today'; 

function GetStr(const aStr: string): string; 
begin 
    Result := TRegEx.Match(aStr, '\$.*/').Value; 
    Result := Copy(Result, 2, Length(Result) - 2); 
end; 

begin 
    Writeln(GetStr(str)); 
    ReadLn; 
end. 

Answer 6

ऊपर कार्यों अगर 2 पाठ भी 1 पैटर्न से पहले दिखाई दे रहा है काम नहीं करेगा ...

आप PosEx()Pos() के बजाय का उपयोग करना चाहिए:

आप स्थिति और कॉपी के साथ यह कर सकते हैं:

function ExtractText(const Str: string; const Delim1, Delim2: string): string; 
var 
    pos1, pos2: integer; 
begin 
    result := ''; 
    pos1 := Pos(Delim1, Str); 
    if pos1 > 0 then begin 
    pos2 := PosEx(Delim2, Str, pos1+1); 
    if pos2 > 0 then 
     result := Copy(Str, pos1 + 1, pos2 - pos1 - 1); 
    end; 
end; 

Answer 7

सभी

function ExtractText(const Str: string; const Delim1, Delim2: string): TStringList; 
var 
    c,pos1, pos2: integer; 
begin 
    result:=TStringList.Create; 
    c:=1; 
    pos1:=1; 

    while pos1>0 do 
    begin 
    pos1 := PosEx(Delim1, Str,c); 
    if pos1 > 0 then begin 
     pos2 := PosEx(Delim2, Str, pos1+1); 
    if pos2 > 0 then 
     result.Add(Copy(Str, pos1 + length(delim1), pos2 - (length(delim1) + pos1))); 
     c:=pos1+1; 
    end; 

    end; 
end;