केवल करते हैं दिन ... बैच फ़ाइल

Question

हैलो मैं एक बैच फ़ाइल, कुछ इस तरह है:

if %day%==monday, tuesday, wednesday, thursday, friday (
goto yes 
) else (
goto no 
) 

अब मुझे पता है पहली पंक्ति काम नहीं करेगा।

यह automatticly चेकों जो दिन है:

क्या मैं वास्तव में ऐसा करना चाहते हैं। यदि सोमवार से शुक्रवार है, तो उसे 'हां' जाना है, अन्यथा (शनिवार/रविवार) को 'नहीं' पर जाना है।

यह कैसे करें?

Answer 1

मैं इस ऑनलाइन भर में भाग गया। परीक्षण किया, और यह काम करता है। दिन को एक पूर्णांक के रूप में वापस कर देता है, जिसे आप अभी भी साथ काम कर सकते हैं।

@For /F "tokens=2,3,4 delims=/ " %%A in ('Date /t') do @( 
    Set Month=%%A 
    Set Day=%%B 
    Set Year=%%C 
) 

@echo DAY = %Day% 
@echo Month = %Month% 
@echo Year = %Year% 

Answer 2

IF %day% == monday GOTO YES 
IF %day% == tuesday GOTO YES 
IF %day% == wednesday GOTO YES 
IF %day% == thursday GOTO YES 
IF %day% == friday GOTO YES 
GOTO NO 

Answer 3

मैं बैच फू के रूप में पूछा सवाल का जवाब देने की जरूरत नहीं है, लेकिन, यह मानते हुए है एक Windows बैच फ़ाइल, कार्य अनुसूचक, जो आप अनुसूची की तरह निर्धारित करने देगा का उपयोग कर स्क्रिप्ट निष्पादित करने पर विचार आप पूछ रहे हैं

Answer 4

यहाँ एक उदाहरण बल्ला फ़ाइल उस चीज़ की इस तरह मुझे यकीन है कि आप अन्य तरीकों इस नमूना कोड का उपयोग करने के बारे में सोच सकते कर रहा हूँ कर देगा। उदाहरण के लिए जब भी आपको "इन" सूची की आवश्यकता होती है। मुश्किल बिट% दिनांक है: ~ 0,3% यह कहता है कि% date% पर्यावरण चर का विस्तार करें और स्ट्रिंग की शुरुआत 0 स्थिति से शुरू होने पर अगले 3 वर्णों को वापस कर दें। आप इसके बारे में "सेट /?" से और जान सकते हैं आदेश।

उदाहरण: IsWeekDay.bat

@echo off 
setlocal 

for %%i in (Mon,Tue,Wed,Thu,Fri) do (
    if "%date:~0,3%"=="%%i" goto YES 
) 

:NO 
echo No 
goto EOF 

:YES 
echo Yes 

:EOF 
endlocal 

Answer 5

Jay के रूप में उल्लेख किया है, date /t का उपयोग कर केवल स्थानों पर काम करेंगे जहां इस आदेश तारीख के साथ आउटपुट सप्ताह के दिन, और अन्य पर काम नहीं करेगा लोकेशंस (जैसे रूसी)। यदि आपको कुछ बैब फ़ाइलों को कुछ वीबीस्क्रिप्ट के साथ मिश्रित करने में कोई फर्क नहीं पड़ता है, तो यहां एक समाधान है जो सभी स्थानों पर काम करना चाहिए।

WScript.Echo DatePart("w", Date) 

आप इस स्क्रिप्ट को चलाने कर सकते हैं:

चाल इस छोटे से VBScript स्क्रिप्ट कि एक नंबर (1 = रविवार, 2 = सोमवार, ... 7 = शनिवार) के रूप में सप्ताह के दिन आउटपुट है अपने बैच फ़ाइल से, इसके उत्पादन पढ़ सकते हैं और अपने तर्क लागू होते हैं:

for /f %%d in ('cscript dayofweek.vbs //nologo') do (
    if %%d==7 goto no :: Saturday 
    if %%d==1 goto no :: Sunday 
) 
goto yes 

Answer 6

यहाँ एक बैच फ़ाइल है कि लगभग एक स्थान-निष्पक्ष तरीके से दिन के सप्ताह, दिन, महीने और वर्ष निकालता है।

एकमात्र लोकेल विशिष्ट बात दिन के सप्ताह की वर्तनी है, शेष लोकल तटस्थ है।

तो अंग्रेजी में, यह गुरुवार के लिए Thu वापस करेगा, लेकिन डच में do (डोंडरडाग के लिए) होगा।

:: http://stackoverflow.com/questions/203090/how-to-get-current-datetime-on-windows-command-line-in-a-suitable-format-for-usi 
:: Works on any NT/2k machine independent of regional date settings 
:: 
:: 20110103 - adapted by jeroen@pluimers.com for Dutch locale 
:: 20110303 - adapted by jeroen@pluimers.com for day-of-week 
:: Dutch will get jj as year from echo:^|date, so the '%%c' trick does not work as it will fill 'jj', but we want 'yy' 
:: luckily, all countries seem to have year at the end: http://en.wikipedia.org/wiki/Calendar_date 
::   set '%%c'=%%k 
::   set 'yy'=%%k 
:: 
:: Also, in Dutch, there is a difference between %date% and date/t: the former will not include 
:: the day-of-the-week, but the latter will. 
:: That means the if "%date%A" LSS "A" trick does not work with %date%, we need a loop 
:: to check if the day-of-the-week needs us to take tokens 2-4 in stead of 1-3: 
::  if "%date%A" LSS "A" (set toks=1-3) else (set toks=2-4) 
::  for /f "tokens=1" %%t in ('date/t') do (...) 
:: 
:: Another difference between Dutch and English is that the Dutch date/t will prepend the day of the week in a lower case 2-letter form. 
:: So the LSS "A" trick needs to be replaced with an LSS "a" trick 
::  if "%date%A" LSS "A" (set toks=1-3) else (set toks=2-4) 
::  if "%%ta" LSS "a" (set toks=1-3) else (set toks=2-4) 
:: 
:: In addition, date will display the current date before the input prompt using dashes 
:: in Dutch, but using slashes in English, so there will be two occurances of the outer loop in Dutch 
:: and one occurence in English. 
:: This skips the first iteration: 
::  if "%%a" GEQ "A" 
:: 
:: echo:^|date 
:: Huidige datum: ma 03-01-2011 
:: Voer de nieuwe datum in: (dd-mm-jj) 
:: The current date is: Mon 01/03/2011 
:: Enter the new date: (mm-dd-yy) 
:: 
:: date/t 
:: ma 03-01-2011 
:: Mon 01/03/2011 
:: 
:: The assumption in this batch-file is that echo:^|date will return the date format 
:: using either mm and dd or dd and mm in the first two valid tokens on the second line, and the year as the last token. 
:: 
:: The outer loop will get the right tokens, the inner loop assigns the variables depending on the tokens. 
:: That will resolve the order of the tokens. 
:: 
@ECHO off 
    set v_day_of_week= 
    set v_day= 
    set v_month= 
    set v_year= 

    SETLOCAL ENABLEEXTENSIONS 
     for /f "tokens=1" %%t in ('date/t') do (
     set v_day_of_week=%%t 
     if "%%ta" LSS "a" (set toks=1-3) else (set toks=2-4) 
    ) 
::DEBUG echo toks=%toks% 
     for /f "tokens=2-4 delims=(-)" %%a in ('echo:^|date') do (
::DEBUG echo first token=%%a 
     if "%%a" GEQ "A" (
      for /f "tokens=%toks% delims=.-/ " %%i in ('date/t') do (
      set '%%a'=%%i 
      set '%%b'=%%j 
      set 'yy'=%%k 
     ) 
     ) 
    ) 
     if %'yy'% LSS 100 set 'yy'=20%'yy'% 
     set Today=%'yy'%-%'mm'%-%'dd'% 

    ENDLOCAL & SET day_of_week=%v_day_of_week% & SET v_year=%'yy'%& SET v_month=%'mm'%& SET v_day=%'dd'% 

    ECHO Today is Year: [%V_Year%] Month: [%V_Month%] Day: [%V_Day%] 
    set datestring=%V_Year%%V_Month%%V_Day% 
    echo %datestring% 
    echo day of week=%day_of_week% 

    :EOF 

इसके साथ मजा लें!

--jeroen

Answer 7

this answer से

, हम

wmic path win32_localtime get dayofweek 

इस this thread में सुझावों के आधार पर पर विस्तार है, हम एक DAYOFWEEK चर के रूप में इस सेट कर सकते हैं:

@echo off 
REM Unset dayofweek in case set in a previous execution of this batch file 
set dayofweek= 
REM Get dayofweek into a variable. Locale-specific: 0 is either Sunday or Monday. 
for /F "skip=1 tokens=*" %%a in ('wmic path win32_localtime get dayofweek') do if not defined dayofweek set dayofweek=%%a 
echo %dayofweek% 

ध्यान दें कि 0 आपके लोकेल के आधार पर रविवार या सोमवार हो सकता है।